XtGem.com

folders used in this test are
/filelist_folder/files
and
/filelist_folder/descriptions

In the script
the files folder is relative to the root directory
the descriptions folder is relative to the current directory

The description files must have the same name as the download file WITHOUT an extension
The descriptions can be html and built with the building tool or plain text
If the description is a html page
Only the content between the body tags (including the container) is used
the rest is ignored
Any html javascript most xt functions and xt widgets can be used in the description
Some functions and widgets may not work correctly due to parsing order
So experiment to see what will work for you
You cannot use php or xtscript in the descriptions

xt script

function lister $path;$descr
# The filelist
# Set the paths

# Set the filelist template MUST BE ALL ON 1 LINE
var $template=<a href=".file_url.">.file_name_parsed.</a><br />.file_size.<br />.file_datetime.
var $template=call htmlspecialchars $val=$template

#Get the filelist
var $filelist=<xt:filelist sort_type="name" sort_dir="desc" folder="$path" template="||.file_name_base.@@$template##" per_page="3" filter="*.*"/>

# The outer holder
print <div class="xt_list">

@loop

# Get the entry
var $offset=call strpos $haystack=$filelist;$needle=||;$offset=$offset
var $end_file_substring=call strpos $haystack=$filelist;$needle=##;$offset=$offset
var $file_substring=call substr $val=$filelist;$start=($offset+2);$length=($end_file_substring-$offset-2)

# Get the file base name (no file extension)
var $file_name_base_end =call strpos $haystack=$file_substring;$needle=@@;
var $file_name_base=call substr $val=$file_substring;$start=0;$length=$file_name_base_end

# Get the rest of the template
var $list_entry=call substr $val=$file_substring;$start=($file_name_base_end +2);

# Get the content of the description file 
var $description=call source $file=$descr/$file_name_base;$html_safe=0;
# Check for body tags
var $description_content_offset=call strpos $haystack=$description;$needle=<body;
# Extract just the content of the body tags
if $description_content_offset
var $description_content_start=call strpos $haystack=$description;$needle=>;$offset=$description_content_offset
var $description_content_end=call strpos $haystack=$description;$needle=</body;$offset=$description_content_offset
var $description=call substr $val=$description;$start=($description_content_start+1);$length=($description_content_end-$description_content_start-1) 
endif

# output the entry change this to suit your needs
print {{
<div class="xt_item">
<div class="xt_description">$description</div>
$list_entry
</div><hr />
}}

# Loop back for next entry
var $offset=call strpos $haystack=$filelist;$needle=||;$offset=($offset+2)
if $offset > 0
goto @loop
endif

# Get the paging code from the filelist
var $paging_code_start=call strrpos $haystack=$filelist;$needle=##
var $paging_code=call substr $val=$filelist;$start=($paging_code_start+2);

# Output the paging code and close the outer holder
print $paging_code </div>
endfunction