XtGem.com

# Default channel name
get_or_default youtube_user;slottyslot
# Videos per page
var $per_page=3

# Other query string values
get_or_default page;1
get vid

# Set initial values
var $count=1
var $offset=3

# Get rss feed
var $raw_feed=<xt:feed feed="http://gdata.youtube.com/feeds/base/users/$youtube_user/uploads?alt=rss&v=2&orderby=published&client=ytapi-youtube-profile" number="0" template="||.title..description.¦.pubDate." >||
var $raw_feed_end=call strlen $val=$raw_feed

# Create the same containers as blog post list
print <div class="xt_blog_parent" id="tube"><div class="xt_list"><div class="xt_blog_post_list">

# Main loop
var $device=<xt:get_device_template />
@loop

# discard entries not on this page
if $count > ($page*$per_page)
goto @skip_output
elseif $count <= ($page-1*$per_page)
goto @skip_output
endif

# Chop up feed entry

# Title
var $start_video_title=($offset-1)
var $end_video_title=call strpos $haystack=$raw_feed;$needle=<div;$offset=$offset
var $youtube_video_title=call substr $val=$raw_feed;$start=$start_video_title;$length=($end_video_title-$start_video_title)

# Id code
var $start_video_code=call strpos $haystack=$raw_feed;$needle=?v=;$offset=$offset
var $end_video_code=call strpos $haystack=$raw_feed;$needle=&amp;;$offset=$offset
var $youtube_video_code=call substr $val=$raw_feed;$start=($start_video_code+3);$length=($end_video_code-$start_video_code-3)

# Description
var $start_video_description=call strpos $haystack=$raw_feed;$needle=<span>;$offset=$offset
var $end_video_description=call strpos $haystack=$raw_feed;$needle=</span>;$offset=$offset
var $youtube_video_description=call substr $val=$raw_feed;$start=($start_video_description+6);$length=($end_video_description-$start_video_description-6)

# Length
var $start_video_length=call strpos $haystack=$raw_feed;$needle=Time:;$offset=$offset
var $end_video_length=call strpos $haystack=$raw_feed;$needle=</span></td>;$offset=$offset
var $youtube_video_length=call substr $val=$raw_feed;$start=($start_video_length+79);$length=($end_video_length-$start_video_length-79)

# Views
var $start_video_views=call strpos $haystack=$raw_feed;$needle=Views;$offset=$offset
var $end_video_views=call strpos $haystack=$raw_feed;$needle=div style="white-space:;$offset=$offset
var $youtube_video_views=call substr $val=$raw_feed;$start=($start_video_views+14);$length=($end_video_views-$start_video_views-22)

# Rating images
var $start_video_rating=call strpos $haystack=$raw_feed;$needle=<div style="white-space:;$offset=$offset
var $end_video_rating=call strpos $haystack=$raw_feed;$needle=gif"></div>;$offset=$offset
var $youtube_video_rating=call substr $val=$raw_feed;$start=$start_video_rating;$length=($end_video_rating+11-$start_video_rating)
var $semi=call chr $val=59
var $youtube_video_rating=call str_replace $subject=$youtube_video_rating;$search=le=";$replace=le="display:inline$semi
var $youtube_video_rating=call str_replace $subject=$youtube_video_rating;$search=align="top";$replace

# Upload date
var $start_upload_date=call strpos $haystack=$raw_feed;$needle=¦;$offset=$offset
var $end_upload_date=call strpos $haystack=$raw_feed;$needle=+0000;$offset=$offset
var $youtube_video_upload_date=call substr $val=$raw_feed;$start=($start_upload_date+2);$length=($end_upload_date-$start_upload_date-2)

# Output entry as blog post list entry
print <div id="vid$count" class="xt_item">
print <h2 class="xt_heading" style="display:block;text-decoration:none;">$youtube_video_title</h2>

# Mobiles get youtube links
if $device==mobile
print <a href="http://www.youtube.com/watch?v=$youtube_video_code"><img alt="" src="http://i.ytimg.com/vi/$youtube_video_code/default.jpg"></a>

# Show selected video (web/touch only)
elseif $vid==$count
print <xt:embed_video url="http://www.youtube.com/watch?v=$youtube_video_code" />
else

# Web/touch get links to embed the video
print <a href="?youtube_user=$youtube_user&amp;vid=$count&amp;page=$page#vid$count"><img alt="" src="http://i.ytimg.com/vi/$youtube_video_code/default.jpg"></a>
endif

# Entry details
print <div class="xt_description" ><div class="xt_text normal" style="word-wrap:break-word;overflow:hidden;">$youtube_video_description</div>
print <div class="xt_label" style="display:block"><label style="display:inline">$uploaded </label>$youtube_video_upload_date</div>
print <div class="xt_label" style="display:block"><label style="display:inline">$length </label>$youtube_video_length</div>
print <div class="xt_label" style="display:block"><label style="display:inline">$views </label>$youtube_video_views</div>
print <div class="xt_label" style="display:block"><label style="display:inline">$rating </label>$youtube_video_rating</div>
print </div>
print </div>

@skip_output
# Move to next entry
var $offset=call strpos $haystack=$raw_feed;$needle=||;$offset=($offset+3)
var $offset=($offset+3)

# loop back if still more entries
if $offset < $raw_feed_end
var $count=($count+1)
goto @loop
endif
print </div></div>

# Pagination
print <div class="xt_container"><div class="xt_pagination">

#  Previous page
if $page >1
print <span><a href="?page=1&amp;youtube_user=$youtube_user#tube"><span>&laquo; </span></a></span>
print <span><a href="?page=($page-1)&amp;youtube_user=$youtube_user#tube"><span>
call floor $num=($page-1)
print </span></a></span>
else

# No previous page
print <span><a><span>&bull;&bull;</span></a></span>
print <span><a><span>&bull;</span></a></span>
endif

# Current page
print <span class="selected"><span>$page</span></span>

# Next page
if $page < ($count/$per_page)
print <span><a href="?page=($page+1)&amp;youtube_user=$youtube_user#tube"><span>
call floor $num=($page+1)
print </span></a></span>
var $page_num=call ceil $num=($count/$per_page)
print <span><a href="?page=$page_num&amp;youtube_user=$youtube_user#tube"><span>&raquo;</span></a></span>
else

# No next page
print <span><a><span>&bull;</span></a></span>
print <span><a><span>&bull;&bull;</span></a></span>
endif
print </div></div>

# Close blog post list  containers
print </div>

Youtube rss feed